#!/bin/csh
#
#------------------------------------------------------------------------
# Name:         fxlogin.csh
#
# Description:  This text file is sourced by opus_login.csh and sets
#               various environment variables.
#
# Usage:        source fxlogin
#
# History:
# Date     OPR      Who       Reason
# -------- ------   --------  ---------------------------------------------
# 04/22/97 33431    WMiller   Initial code
# 08/07/97 34946    MARose    Change definitions for uid directories
# 02/11/98 36175.3  MARose    Change SI_UID to SHARE_UID
# 02/25/98 36397    WMiller   Add Linux definitions for UID variables
# 04/28/98 36655    MSwam     Replace HOSTTYPE test with 'uname -s'
# 02/14/00 40675    WMiller   Replace version output with variable definition
# 06/28/00 41693_11 MSwam     Add HST-specific PODPS_CLD for CALFOC
# 01/31/03 47450    Sontag    Added lines for AIX
#------------------------------------------------------------------------
#
setenv PLOT_INIT SOGS_DISK:/dat/
#
#-----------------------------------------------------------------------------
# Define dayfile variables.
#-----------------------------------------------------------------------------
setenv SOGS_SDAYR OPUS_HOME_DIR
setenv SOGS_UDAYR OPUS_HOME_DIR
setenv USER_DAYFILE OPUS_HOME_DIR:opus.day
#
#-----------------------------------------------------------------------------
# Share run-time variables:
#-----------------------------------------------------------------------------
setenv SI_HLP SOGS_DISK:/hlp/
setenv SHARE_HLP SOGS_DISK:/hlp/
#
#-----------------------------------------------------------------------------
# OPUS platform-dependent variables:
#-----------------------------------------------------------------------------
set opsys = `uname -s`
switch ( $opsys )
   case OSF1:
     setenv SHARE_UID SOGS_DISK:/uid/axp_unix/
     setenv OPUS_UID SOGS_DISK:/uid/axp_unix/
     breaksw
   case SunOS:
     setenv SHARE_UID SOGS_DISK:/uid/sparc_solaris/
     setenv OPUS_UID SOGS_DISK:/uid/sparc_solaris/
     breaksw
   case Linux:
     setenv SHARE_UID SOGS_DISK:/uid/linux/
     setenv OPUS_UID SOGS_DISK:/uid/linux/
     breaksw
   case AIX:
     setenv SHARE_UID SOGS_DISK:/uid/ibm_aix/
     setenv OPUS_UID SOGS_DISK:/uid/ibm_aix/
     breaksw
   default:
     echo ""
     echo "WARNING: System type $opsys unknown- SHARE_UID and OPUS_UID not set"
     echo ""
     unsetenv SHARE_UID 
     unsetenv OPUS_UID 
endsw
#
#-----------------------------------------------------------------------------
# OPUS run-time variables:
#-----------------------------------------------------------------------------
setenv OPUS_HLP SOGS_DISK:/hlp/
setenv OPUS_DAT SOGS_DISK:/dat/
setenv OPUS_DBMS_LOAD SOGS_DISK:/dbms/load/
setenv PODPS_CLD anyoldvalue  # CALFOC uses this to trap pipeline mode
#                                  
setenv MSGRPT_REPORT_LEVEL MSGRPT_INFO
#
set version_file = `osfile_stretch_file OPUS_DAT:testbed.ver`
set noglob
set val = `/bin/cat $version_file | /bin/awk '{for(i=1;i<=NF;i++) printf $i" "}'`
setenv OPUS_VERSION "$val"
unset noglob
#
